Star Festival... a Return to Japan/Star Festival... a Return to Japan.iso/pc/STARFESTIVAL/3dcd/Animraw.dir/00001_Start.ls

Text File | 1999-04-28 | 3.3 KB | 123 lines

on startMovie
  global GSFpathname, gEngButtonSprite, gCursorReady, gplaybtnsprite, gPcVidSprite
  set the mouseDownScript to EMPTY
  set the mouseUpScript to EMPTY
  gEngButtonSprite = 8
  gCursorReady = 1
  gplaybtnsprite = 0
  gPcVidSprite = 52
  puppetSprite(46, 1)
end

on stopMovie
  stopmovieqt()
end

on idle
  global gCursorReady
  if gCursorReady = 1 then
    cursor(200)
    checkCursors()
    set the locH of sprite 46 to the mouseH
    set the locV of sprite 46 to the mouseV
    updateStage()
  end if
  qtidle()
end

on checkCursors
  setzeoIdle()
  set the castNum of sprite 46 to the number of member "curs1"
  if rollOver(2) then
    set the castNum of sprite 46 to the number of member "cursDown"
  end if
  if the castNum of sprite 3 and rollOver(3) then
    set the castNum of sprite 46 to the number of member "cursLeft"
  end if
  if the castNum of sprite 4 and rollOver(4) then
    set the castNum of sprite 46 to the number of member "cursRight"
  end if
  if rollOver(7) then
    set the castNum of sprite 46 to the number of member "hotCursor"
  end if
  if rollOver(8) and sprite(8).visible then
    set the castNum of sprite 46 to the number of member "hotCursor"
  end if
  if the castNum of sprite 9 and rollOver(9) then
    set the castNum of sprite 46 to the number of member "cursUp"
  end if
  if the castNum of sprite 10 and rollOver(10) then
    set the castNum of sprite 46 to the number of member "cursDown"
  end if
  if the castNum of sprite 11 and rollOver(11) then
    set the castNum of sprite 46 to the number of member "nonCursor"
  end if
  if rollOver(13) or rollOver(14) then
    set the castNum of sprite 46 to the number of member "hotCursor"
  end if
  if rollOver(20) then
    set the castNum of sprite 46 to the number of member "hotCursor"
  end if
end

on setzeoIdle
  global gPcVidSprite, zeoIdle
  zeoIdle = 0
  if the memberNum of sprite gPcVidSprite > 0 then
    if sprite(gPcVidSprite).movieRate > 0 then
      zeoIdle = 1
    end if
  end if
end

on quickSwitch theSound
  channel = the clickOn
  puppetSprite(channel, 1)
  if theSound <> "none" then
    puppetSound(theSound)
  end if
  theCast = cast(the castNum of sprite channel).name
  set the castNum of sprite channel to the number of member (theCast & "B")
  updateStage()
  repeat while soundBusy(1)
  end repeat
  repeat while the stillDown
  end repeat
  set the castNum of sprite channel to the number of member theCast
  updateStage()
  puppetSprite(channel, 0)
end

on engSwitch theSound
  global gEngButtonSprite
  if theSound <> "none" then
    puppetSound(theSound)
  end if
  theName = member(the castNum of sprite gEngButtonSprite).name
  case theName of
    "shrEngOffUp":
      set the castNum of sprite gEngButtonSprite to the number of member "shrEngOffDown"
      updateStage()
      repeat while the stillDown
      end repeat
      set the castNum of sprite gEngButtonSprite to the number of member "shrEngOnUp"
      voicEng()
      updateStage()
    "shrEngOnUp":
      set the castNum of sprite gEngButtonSprite to the number of member "shrEngOnDown"
      updateStage()
      repeat while the stillDown
      end repeat
      set the castNum of sprite gEngButtonSprite to the number of member "shrEngOffUp"
      voicNih()
      updateStage()
  end case
end

on myreturn
  global GSFpathname
  quickSwitch("vidClick")
  go("xitS")
  go(1, GSFpathname & "19r")
end